Hitung Manual One Way Anova – Uji ANOVA dengan Excel

Hitung Manual Uji Anova dengan Excel

Apabila pada artikel sebelumnya kita mempelajari cara melakukan uji one way anova dengan excel menggunakan tool data analysis toolpak, maka pada kesempatan ini kita akan belajar menggunakan excel sebagai media untuk perhitungan secara manual. Tujuannya adalah agar kita tidak bergantung penuh pada tool data analysis toolpak dan kita bisa lebih mengerti bagaimana sebenarnya perhitungan uji one way anova dilakukan. Dalam artikel ini kita akan belajar cara Uji ANOVA dengan Excel.

Agar anda lebih memahami tutorial one way anova dengan excel ini, maka sebaiknya anda pelajari terlebih dahulu rumus rumus manualnya. Untuk menambah wawasan, anda juga kami anjurkan mempelajari tentang one way anova dengan excel dan one way anova dalam SPSS.

Asumsi Uji ANOVA

Tentunya dalam uji one way anova yang sesungguhnya, kita harus memperhatikan masalah asumsi. Asumsi pada one way anova antara lain:

1. Skala data variabel dependen berskala interval atau rasio.
2. Variabel independen terdiri dari 2 kategori atau lebih.
3. Tiap Kategori bersifat independen dalam observasinya, artinya partisipan atau sumber data masing-masing kategori berbeda. Apabila kategorinya berasal dari sumber yang sama maka gunakan model lain, yaitu uji repeated measure one way anova.
4. Tidak ada outlier di dalam data. Outlier adalah data pencilan atau adanya sebuah observasi atau sebuah sampel yang nilainya berbeda jauh dengan observasi atau sampel yang lainnya.
5. Ada kesamaan varians antar kategori atau yang disebut dengan homogen.
6. Variabel dependen berdistribusi normal.

Asumsi ANOVA Yang Dihitung

Asumsi nomor 1 sampai dengan 3 tidak perlu diuji secara statistik, tapi anda gunakan logika untuk mengatasinya. Sedangkan nomor 4 sampai dengan 6 harus anda uji secara statistik. Jadi anda harus melakukan uji normalitas misal uji lilliefors, uji homogenitas misal uji Bartlett dan membuat Steam Leaf untuk menentukan adanya outlier. Untuk memahami asumsi nomor 4 sampai dengan 6 tersebut, anda dapat mempelajari dalam artikel kami:

1. Normalitas Pada SPSS
2. Uji Normalitas
3. Normalitas Excel
4. Uji Homogenitas
5. Fisher F

Langsung saja kita masuk pada bahasan inti, misal kita akan menentukan apakah metode belajar mempengaruhi nilai ujian. Metode belajar dibagi dalam 4 kategori (lihat asumsi nomor 2). Jadi masing-masing metode memiliki sejumlah sampel atau orang yang diobservasi. Artinya masing-masing metode bersifat independen (lihat asumsi nomor 2). Yang menjadi bahan observasi adalah nilai ujian, dimana nilai ujian berkisar antara nilai 0 sampai dengan 100, di mana nilai tersebut adalah angka numerik dengan nilai 0 absolut atau yang disebut juga berskala rasio (lihat asumsi nomor 3).

Uji ANOVA dengan EXCEL

Sebelum lebih jauh, alangkah lebih mudahnya anda mempelajari artikel ini jika anda mendownload file kerja dalam tutorial ini di link INI. Atau anda bisa lihat file kerja dalam embed di bawah ini.

Cara Melakukan Uji ANOVA dengan Excel

Langkah awal:

1. Buka aplikasi excel anda
2. Isi data pada cell B6 sd B34 dengan kategorinya pada cell A6 sd A36 (lihat contoh)
3. Setelah anda buat data tersebut, coba kelompokkan metode 1 pada cell D6 sd D12, metode 2 pada cell E6 sd E13, metode 3 pada cell F6 sd F13 dan metode 4 pada cell G6 sd G12.

Langkah Menentukan Nilai Alpha dan Menghitung Jumlah sampel:

1. Tentukan nilai alfa atau batas kritis penelitian, yaitu isi dengan 0,05 pada cell J7.
2. Buat simbol grup pada I11 sd I14.
3. J11: =COUNT(D6:D13)
4. J12: =COUNT(E6:E13)
5. J13: =COUNT(F6:F13)
6. J14: =COUNT(G6:G13) artinya anda menghitung jumlah sampel tiap metode.

Langkah Menghitung Jumlah Nilai Ujian Semua Sampel:

1. K11: =SUM(D6:D13)
2. K12: =SUM(E6:E13)
3. K13: =SUM(F6:F13)
4. K14: =SUM(G6:G13) artinya anda menghitung jumlah nilai ujian semua sampel per metode.

Langkah Menghitung Mean:

1. L11: =AVERAGE(D6:D13)
2. L12: =AVERAGE(E6:E13)
3. L13: =AVERAGE(F6:F13)
4. L14: =AVERAGE(G6:G13) artinya anda menghitung mean atau rata-rata nilai ujian semua sampel per metode.

Langkah Menghitung Varians:

1. M11: =VAR(D6:D13)
2. M12: =VAR(E6:E13)
3. M13: =VAR(F6:F13)
4. M14: =VAR(G6:G13) artinya anda menghitung varians nilai ujian semua sampel per metode.

Langkah Menghitung Sum of Squares:

1. N11: =DEVSQ(D6:D13)
2. N12: =DEVSQ(E6:E13)
3. N13: =DEVSQ(F6:F13)
4. N14: =DEVSQ(F6:F13) artinya anda menghitung Sum of Squares (SS) nilai ujian semua sampel per metode. SS rumusnya seperti bawah ini: Jumlah kuadrat dari x dikurangi mean per kategori.

   

   Langkah Menghitung Mean Of Squares:

1. Buat baris Between Groups, Within Groups dan Total pada cell I18, I19 dan I20 secara berurutan.
2. J19: =SUM(N11:N14) artinya menjumlahkan semua nilai SS pada langkah 22 sd 25.
3. J20: =DEVSQ(D6:G13) artinya menghitung Sum of Squares (SS) nilai ujian semua sampel tanpa dikelompokkan per metode.
4. J18: =J20-J19 artinya menghitung selisih antara nilai Total (langkah 28) dengan nilai Within Groups (langkah 27).
5. K18: =COUNTA(I11:I14)-1 artinya menghitung jumlah degree of freedom (DF 1) atau derajat kebebasan 1 yaitu banyaknya kategori atau metode dikurangi 1.
6. K20: =COUNT(D6:G13)-1 artinya menghitung yaitu banyaknya semua sampel dikurangi 1.
7. K19: =K20-K18 artinya menghitung DF 2 yaitu selisih antara banyaknya semua sampel dikurangi 1 (langkah 31) dengan DF 1 (Langkah 30).
8. O11: =SQRT(L$19/J11)
9. O12: =SQRT(L$19/J12)
10. O13: =SQRT(L$19/J13)
11. O14: =SQRT(L$19/J14) artinya menghitung standart error tiap metode.
12. P11: =L11-O11*TINV(J$7,J11-1)
13. P12: =L12-O12*TINV(J$7,J12-1)
14. P13: =L13-O13*TINV(J$7,J13-1)
15. P14: =L14-O14*TINV(J$7,J14-1) artinya menghitung lower limit tiap metode.
16. Q11: =L11+O11*TINV(J$7,J11-1)
17. Q12: =L12+O12*TINV(J$7,J12-1)
18. Q13: =L13+O13*TINV(J$7,J13-1)
19. Q14: =L14+O14*TINV(J$7,J14-1) artinya menghitung upper limit tiap metode.
20. L18: =J18/K18 dan copas hingga L20, artinya menghitung nilai Mean Square (MS) pada Between Groups, Within Groups dan Total.

Langkah Menghitung Nilai F dan Probabilitas:

1. M18: =L18/L19 artinya menghitung nilai F hitung yaitu membagi nilai MS Between Groups dengan MS Within Groups.
2. N18: =FDIST(M18,K18,K19) artinya kita menghitung nilai p value atau nilai signfikansi pada batas kritis atau probabilitas 0,05.
3. O18: =FINV(J7,K18,K19) artinya kita menghitung nilai F tabel pada DF 1 dan DF2 pada taraf signifikansi atau alfa sebesar pada Cell J7 (langkah 4).
4. J22: =IF(M18<=O18,”Tidak Signifikan (pada alfa = “&J7&”)”,”Signifikan (pada alfa = “&J7&”)”) artinya kita akan membuat kesimpulan bahwasanya apakah nilai F hitung lebih besar atau lebih kecil dari pada F tabel. Kesimpulannya adalah: jika F Hitung < F Tabel maka H0 diterima atau yang berarti pengaruh metode pada nilai ujian tidak signifikan pada batas kritis sebesar alfa pada kolom J7. Sebaliknya jika F Hitung > F Tabel maka H0 ditolak atau yang berarti pengaruh metode pada nilai ujian signifikan pada batas kritis sebesar alfa pada kolom J7.
5. J23: =IF(N18>0.05,”Tidak Signifikan (pada alfa = 0.05)”,”Signifikan (pada alfa = 0.05)”) artinya sama dengan langkah 49, hanya saja batas kritis yang ditentukan adalah 0,05. Yaitu bisa dengan langsung melihat nilai P value, apabila p value < 0,05 maka H0 ditolak atau yang berarti pengaruh metode pada nilai ujian signifikan pada batas kritis sebesar alfa 0,05.

Kesimpulan Uji Anova dengan Excel

Pada contoh dalam tutorial ini, nilai alfa pada kolom J7 sebesar 0,05, silahkan ganti dengan nilai yang lain misal 0,1, maka lihat kesimpulannya pada Kolom J22 dan J23 yaitu pada langkah 49 dan 50, tentunya hasilnya akan berbeda.

Demikian tutorial Uji Anova dengan Excel ini, yang dibuat dengan sangat sederhana, tetapi semoga bermanfaat bagi para pembaca.

Baca Juga: Tutorial Anova dengan R Studio lengkap dengan Post Hoc!

By Anwar Hidayat